added solution using imagej

05_BioImage_Analysis_Tools/imagej/BlobImagesSegmentation_exercise.ijm

+// blob segmentation of images in folders
+// 
+// This script analyses folders full of image with blobs and measures their average size
+// 
+// Author: Robert Haase, rhaase@mpi-cbg.de
+// May 2019
+// 
+///////////////////////////////////
+
+folder = "C:/structure/mpicloud/Projects/201909_Teaching_BioImageAnalysis_Praque/prague/05_examples/example_images/";
+
+function main() {
+	run("Clear Results");
+
+	processFolder(folder + "condition_A/");
+	saveAs("Results", folder + "ResultsA.xls");
+	run("Clear Results");
+
+	processFolder(folder + "condition_B/");
+	saveAs("Results", folder + "ResultsB.xls");
+	run("Clear Results");
+}
+
+function processFolder(foldername) {
+
+	filelist = getFileList(foldername);
+	number_of_files_in_folder = lengthOf(filelist);
+
+	// go through all images, segment them and collect results in a table
+	for (i = 0; i < number_of_files_in_folder; i++) {
+		open(foldername + filelist[i]);
+	
+		processImage();
+		
+		close();
+	}
+}
+
+function processImage() {
+	// remoive noise
+	run("Gaussian Blur...", "sigma=5");
+
+	// segment
+	setAutoThreshold("Otsu dark");
+	setOption("BlackBackground", true);
+	run("Convert to Mask");
+	
+	// analyze
+	run("Set Measurements...", "area redirect=None decimal=3");
+	run("Analyze Particles...", "display");
+}
+
+main();